#include <BlynkSimpleStream.h>
#include <Adafruit_NeoPixel.h>
 
char auth[] = "b5b961bbfd0044bbac5a30f94e20d6d0";
 
#define PIN 19
#define NUMPIXELS 3
 
Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);
 
// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  if (WheelPos < 85) {
    return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
  } else if (WheelPos < 170) {
    WheelPos -= 85 ;
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  } else {
    WheelPos -= 170 ;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}

 
int ledR = 0;
int ledG = 0;
int ledB = 0;
int pixelBrightness = 50;
int Mode = 0, j = 0, Speed = 20;
 

BLYNK_WRITE(V0) //pick a color of LED
{
  ledR = param[0].asInt();
  ledG = param[1].asInt();
  ledB = param[2].asInt();
   for(int i=0;i<NUMPIXELS;i++){
    strip.setPixelColor(i, strip.Color(ledR, ledG, ledB));
  }
  strip.show();
}

BLYNK_WRITE(V1) // parameter of LED brightness
{
  pixelBrightness = param.asInt();
  strip.setBrightness(pixelBrightness);
  strip.show();
}

BLYNK_WRITE(V2) //parameter of the pattern of blinking
{
  Mode = param.asInt();
} 

BLYNK_WRITE(V3) //parameter of the speed of color change
{
  Speed = param.asInt();
}

void setup()
{
  Serial.begin(9600); 
  Blynk.begin(Serial, auth);
  Blynk.syncAll();
  strip.begin();
  strip.setBrightness(pixelBrightness);
  strip.show();
}

//a function of changing the color of LEDs like a rainbow
void rainbowCycle(uint8_t wait, uint8_t j) {
  uint16_t i;
  for(i=0; i< strip.numPixels(); i++) {
    strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
  }
  strip.show();
  delay(wait);
}

void loop()
{
  Blynk.run();
  strip.setBrightness(pixelBrightness);
 
  if(Mode == 0){
    //normal mode
    for(int i=0;i<NUMPIXELS;i++){
      strip.setPixelColor(i, strip.Color(ledR, ledG, ledB));
    }
    strip.show();
  }else{
    //rainbow mode
    j++;
    if(j >256){
      j = 0;
    }
    rainbowCycle(Speed, j);
  }
}